home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / lt1225 < prev    next >
Encoding:
Text File  |  1996-07-09  |  4.0 KB  |  128 lines
  1. * 
  2. * Linear Technology LT1225 op amp model  
  3. * Written: 1-26-1993 16:30:32 Type: Bipolar NPN input, internal comp.
  4. * Modified by G.F. to add Cload compensation network and freq. shaping
  5. * Typical specs: 
  6. * Vos=5.0E-04, Ib=4.0E-06, Ios=1.0E-07, GBP=150E+06Hz, Phase mar.= 58 deg, 
  7. * SR(-)=4.0E+02V/us, SR(+)=4.0E+02V/us, Av= 87dB, CMRR=111dB, 
  8. * Vsat(+)=1.300V, Vsat(-)=1.700V, Isc=+40/-40mA, Rout=50ohms, Iq=7.00mA.
  9. * 
  10. * Connections: + - V+V-O 
  11. .SUBCKT LT1225 3 2 7 4 6 
  12. * INPUT
  13. RC1 7  80 9.9909E+02
  14. RC2 7  90 9.9909E+02
  15. Q1  80 2  10 QM1 
  16. Q2  90 3  11 QM2 
  17. CIN 2  3  2.0000E-12
  18. C1  80 90 0.265E-12
  19. *INPUT POLE AT 300MHZ
  20. RE1 10 12 263
  21. RE2 11 12 263
  22. *    RE1, RE2 REDUCED VS LT1224 TO REFLECT HIGHER GM
  23. IEE 12 4  1.4240E-03
  24. RE  12 0  1.4045E+05
  25. * INTERMEDIATE
  26. *MODS: GA DEPENDENCE INVERTED (POLARITY SWAPPED)
  27. *      R2 INCREASED TO 7MOHM (ALL GAIN IN ONE STAGE)
  28. *      C2 TIED TO GROUND (WAS NODE 1), REDUCED TO 3.11PF FROM 3.54PF 
  29. *      GB POLARITY REVERSED, GB=1/R02 FOR GAIN OF 1 
  30. *      RF, CF ADDED FOR CLOAD NETWORK (REDUCES VALUE OF C2)
  31. *      REVERSE POLARITY OF GNL,GPL,GCL,GCM FOR LIMITING BECAUSE OF GA REVERSAL
  32. *      ADD MULTIPLE POLES AND A ZERO BETWEEN GA STAGE AND GB STAGE
  33. GCM 8  0  12 0  1.0009E-08
  34. GA  8  0  90 80 1.0009E-3
  35. R2  8  0  7.0E+06
  36. C2  8  0  3.11E-12
  37. *POLE AT 180MHZ
  38. GX1 0  28 8  0  1E-06
  39. RX1 28 0  1E+06
  40. CX1 28 0  0.885E-15
  41. *POLE AT 180MHZ
  42. GX2 0  38 28 0  1E-06
  43. RX2 38 0  1E+06
  44. CX2 38 0  0.885E-15
  45. *POLE AT 180MHZ
  46. GX3 0  48 38 0  1E-06
  47. RX3 48 0  1E+06
  48. CX3 48 0  0.885E-15  
  49. *ZERO AT 60MHZ
  50. GX4 0  58 48 0  1E-06
  51. RX4 58 59 1E+06
  52. LX4 59 0  2.65E-03
  53. *POLE AT 180MHZ
  54. GX5 0  68 58 0  1E-06
  55. RX5 68 0 1E+06
  56. CX5 68 0 .885E-15
  57. *POLE AT 180MHZ
  58. GX6 0  78 68 0  1E-06
  59. RX6 78 0  1E+06
  60. CX6 78 0  .885E-15
  61. *
  62. GB  0  1  78 0  20.4E-03
  63. RO2 1  0  49
  64. RF  8  99 2400
  65. CF  99 6  5E-12
  66. * OUTPUT 
  67. RSO 1  6  1.0000E+00
  68. ECL 18 0  1  6  2.3987E+01
  69. GCL 8  0  20 0  1.0000E+00
  70. RCL 20 0  1.0000E+01
  71. D1  18 19 DM1  
  72. VOD1 19 20 5.9605E-08
  73. D2  20 21 DM1  
  74. VOD2 21 18 5.9605E-08
  75. * 
  76. D3A 131 70 DM3 
  77. D3B 13 131 DM3 
  78. GPL 8  0  70 7  1.0000E+00
  79. VC  13 6  2.7909E+00
  80. RPLA 7  70 1.0000E+01
  81. RPLB 7  131 1.0000E+03
  82. D4A 60 141 DM3 
  83. D4B 141 14  DM3 
  84. GNL 8  0  60 4  1.0000E+00
  85. VE  6  14 3.1909E+00
  86. RNLA 60 4  1.0000E+01
  87. RNLB 141 4  1.0000E+03
  88. * 
  89. IP  7  4  5.5760E-03
  90. DSUB 4  7  DM2  
  91. * MODELS 
  92. .MODEL QM1 NPN (IS=8.0000E-16 BF=1.7481E+02)
  93. .MODEL QM2 NPN (IS=8.1240E-16 BF=1.7924E+02)
  94. .MODEL DM1  D   (IS=1.0000E-20)
  95. .MODEL DM2  D   (IS=8.0000E-16 BV=4.3200E+01)
  96. .MODEL DM3  D   (IS=1.0000E-16)
  97. .ENDS LT1225
  98. * 
  99. * - - - - - * fini LT1225 * - - - - - *
  100. ***
  101. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1993
  102. *                       All rights reserved.
  103. * 
  104. *   Linear Technology Corporation hereby grants the users of this
  105. * macromodel a non-exclusive, nontransferrable license to use this
  106. *            macromodel under the following conditions:
  107. * 
  108. * The user agrees that this macromodel is licensed from Linear
  109. * Technology and agrees that the macromodel may be used, loaned,
  110. * given away or included in other model libraries as long as this
  111. * notice and the model in its entirety and unchanged is included.
  112. * No right to make derivative works or modifications to the
  113. * macromodel is granted hereby.  All such rights are reserved.
  114. * 
  115. * This model is provided as is.  Linear Technology makes no
  116. * warranty, either expressed or implied about the suitability or
  117. * fitness of this model for any particular purpose.  In no event
  118. * will Linear Technology be liable for special, collateral,
  119. * incidental or consequential damages in connection with or arising
  120. * out of the use of this macromodel.  It should be remembered that
  121. * models are a simplification of the actual circuit.
  122. * 
  123. * Linear Technology reserves the right to change these macromodels
  124. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  125. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  126. * datasheets on the actual amplifiers or the latest macromodels.
  127. * 
  128. * ----------------------------------------------------------------------- *